Chapter 2 (Fig. 2.27) – The mathematical formulation of the super-efficiency CRS-DEA model and the corresponding GAMS formulation

$Title Chapter 2 (Fig. 2.27)
$Title Mathematical formulation of the super-efficiency CRS-DEA model and the corresponding GAMS code

$onText

If using this code, please cite:

---------------------------------------------------------------------------------
Emrouznejad, A., P. Petridis, and V. Charles (2023). Data Envelopment Analysis
with GAMS: A Handbook on Productivity Analysis, and Performance Measurement,
Springer, ISBN: 978-3-031-30700-3.
---------------------------------------------------------------------------------

Website: https://dataenvelopment.com/GAMS/

$offText

Sets    j DMUs /DMU1*DMU10/
        g Inputs and Outputs /ProdCost, TrnCost, HoldInv, SatDem, Rev/
        i(g)  Inputs /ProdCost, TrnCost, HoldInv/
        r(g) Outputs /SatDem, Rev/;
        alias(jj,j);
        alias(k,jj);

Table Data(j,g) Data for inputs and outputs

           ProdCost     TrnCost      HoldInv     SatDem      Rev
DMU1        0.255        0.161        0.373        20        2.64
DMU2        0.98         0.248        0.606        6         5.29
DMU3        0.507        0.937        0.749        17        2.43
DMU4        0.305        0.249        0.841        2         8.99
DMU5        0.659        0.248        0.979        19        2.94
DMU6        0.568        0.508        0.919        17        0.75
DMU7        0.583        0.628        0.732        17        6.36
DMU8        0.627        0.675        0.738        10        7.2
DMU9        0.772        0.657        0.486        9         2.16
DMU10       0.917        0.639        0.234        8         7.3;


Variables efficiency objective function
          z(i)     efficiency (Theta values)
          Lambda(j) dual weights (Lambda values)

Nonnegative variables
          Lambda(j)
          z(i);

Parameters DMU_data(g) slice of data
           eff(j) efficiency report
           Lamres(j,j) peers for each DMU
           res_z(j,i) results for '�' variable
           cc order of DMU under investigation 'o';


Equations OBJ objective function
          CON1(i) input duals
          CON2(r) output dual;

OBJ..       efficiency=E=1+(1/CARD(i))*SUM(i,z(i));

CON1(i)..  SUM(j$(ORD(j)<>cc), Lambda(j)*Data(j,i))-z(i)*DMU_data(i)=L=DMU_data(i);

CON2(r)..  SUM(j$(ORD(j)<>cc), Lambda(j)*Data(j,r))=G=DMU_data(r);

model DEA_Super_non_radial_efficiency_CRS input oriented DEA CRS / OBJ, CON1, CON2 /;

loop(jj,
   DMU_data(g) = Data(jj,g);
   cc=ORD(jj);
   solve DEA_Super_non_radial_efficiency_CRS using LP minimizing Efficiency ;
   eff(jj)=Efficiency.l;
   res_z(j,i)=z.l(i);
   loop(k,
      Lamres(jj,k)=Lambda.l(k);
    );
);

Display eff, res_z, Lamres;

Execute_unload