Chapter 6 (Fig. 6.01) – The Mathematical formulation for BoD model and the corresponding GAMS code

$Title Chapter 6 (Fig. 6.1)
$Title Mathematical formulation for BoD model and the corresponding GAMS code

$onText

If using this code, please cite:

---------------------------------------------------------------------------------
Emrouznejad, A., P. Petridis, and V. Charles (2023). Data Envelopment Analysis
with GAMS: A Handbook on Productivity Analysis, and Performance Measurement,
Springer, ISBN: 978-3-031-30700-3.
---------------------------------------------------------------------------------

Website: https://dataenvelopment.com/GAMS/

$offText

Sets    i criteria /C1*C6/
        j alternatives /Alt1*Alt10/;

Parameters

res_w(i) results of weights for each criterion i
CI(j) Sub-Composite Indicator of alternative j;


Table x(j,i) Alternative rating as per 6 criteria
           C1       C2        C3       C4       C5       C6
Alt1        2        2        3        2        1        1
Alt2        2        3        1        2        2        2
Alt3        2        2        1        2        2        1
Alt4        1        2        1        3        2        2
Alt5        2        2        3        2        1        1
Alt6        3        2        1        2        3        3
Alt7        1        2        3        2        1        2
Alt8        1        2        1        2        1        1
Alt9        1        2        2        2        3        2
Alt10       1        2        3        1        3        1;



Variables z
Nonnegative variables w(i) weights;

Equations
OBJ
CON2(j);

OBJ..       z=E=SUM(i,SUM(j,w(i)*x(j,i)));
CON2(j)..   SUM(i,w(i)*x(j,i))=L=1;

Model BoD/ALL/;

Solve BoD maximizing z using LP;
res_w(i)=w.l(i);
CI(j) = SUM(i,res_w(i)*x(j,i));

Display res_w, CI;

execute_unload;