Chapter 4 (Fig. 4.06) – (The mathematical formulation of the RAM model

$Title Chapter 4 (Fig. 4.6)
$Title Mathematical formulation of the RAM model and the corresponding GAMS code

$onText

If using this code, please cite:

---------------------------------------------------------------------------------
Emrouznejad, A., P. Petridis, and V. Charles (2023). Data Envelopment Analysis
with GAMS: A Handbook on Productivity Analysis, and Performance Measurement,
Springer, ISBN: 978-3-031-30700-3.
---------------------------------------------------------------------------------

Website: https://dataenvelopment.com/GAMS/

$offText

Sets    j DMUs /DMU1*DMU10/
        g Inputs and Outputs /ProdCost, TrnCost, HoldInv, SatDem, Rev/
        i(g)  Inputs /ProdCost, TrnCost, HoldInv/
        r(g) Outputs /SatDem, Rev/;
        alias(jj,j);
        alias(k,jj);

Table Data(j,g) Data for inputs and outputs

           ProdCost     TrnCost      HoldInv     SatDem      Rev
DMU1        0.255        0.161        0.373        20        2.64
DMU2        0.98         0.248        0.606        6         5.29
DMU3        0.507        0.937        0.749        17        2.43
DMU4        0.305        0.249        0.841        2         8.99
DMU5        0.659        0.248        0.979        19        2.94
DMU6        0.568        0.508        0.919        17        0.75
DMU7        0.583        0.628        0.732        17        6.36
DMU8        0.627        0.675        0.738        10        7.2
DMU9        0.772        0.657        0.486        9         2.16
DMU10       0.917        0.639        0.234        8         7.3;


Variables efficiency objective function for RAM model
          Lambda(j) dual weights (Lambda values)
          sminus(i) slacks assigned to inputs
          splus(r) slacks assigned to outputs;

Nonnegative variables
          Lambda(j)
          sminus(i)
          splus(r);

Parameters DMU_data(g) slice of data
           eff(j) optimal values objective function
           slice_theta(i) slice of efficiency for second stage of non-radial model
           lamres(j,j) peers for each DMU
           slacks(j,g) slacks for inputs and outputs
           Rminus(i) range for inputs i
           Rplus(r) range for outputs r
           m cardinal of set of inputs
           s cardinal of set of outputs ;

Rminus(i)=smax(j,Data(j,i))- smin(j,Data(j,i));
Rplus(r)=smax(j,Data(j,r))- smin(j,Data(j,r));

m=CARD(i);
s=CARD(r);



Equations OBJ objective function
          CON1(i) input duals
          CON2(r) output dual
          CON3(i) upper bound for input slack
          CON4(r) upper bound for output slack
          CON5 VRS;


OBJ..       efficiency=E=1-1/(m+s)*{SUM(i,sminus(i)/Rminus(i))+SUM(r,splus(r)/Rplus(r))};

CON1(i)..  SUM(j, Lambda(j)*Data(j,i))+sminus(i)=E=DMU_data(i);

CON2(r)..  SUM(j, Lambda(j)*Data(j,r))-splus(r)=E=DMU_data(r);

CON3(i)..  sminus(i)=L=Rminus(i);

CON4(r)..  splus(r)=L=Rplus(r);

CON5..     SUM(j, Lambda(j))=E=1;


model RAM Range Adjusted Measure model
         / OBJ, CON1, CON2, CON3, CON4, CON5/;

loop(jj,
   DMU_data(g) = Data(jj,g);
   solve RAM using LP maximizing efficiency;
   eff(jj)=efficiency.l;
   loop(k,
      Lamres(jj,k)=Lambda.l(k);
    );
);

Execute_unload